`* -------------------------------------------
`* LIB_THIEF EXEC v1.00
`*
`* © 27.08.2005 by Volker Stepprath, Testaware
`*
`* Example how to use the LIB_Thief.exe
`* and analysis of its param results!
`* -------------------------------------------

repeat

   a = LIB_ColorRequest()
   cls a : sync
   print hex$(a)

   print LIB_OpenFileRequest("Select file to open","","",0)
   print LIB_SaveFileRequest("Save file as","","",0)
   print LIB_PathRequest("Select folder for work",get dir$())
   print LIB_InputRequest("Input Requester","Please enter text:","")
   print LIB_MessageRequest("Message Requester","Simply press the OK button...")

   a = LIB_AskRequest("Ask Requester","Do you want exit example?")
   print a

until a = 1

wait key

`****************************************************
`* LIB_THIEF EXEC Functions
`****************************************************

FUNCTION LIB_OpenFileRequest(a$,b$,c$,a)

   `* Open standard File Requester to open file
   `* -----------------------------------------
   `* a$ => Windowtitle
   `* b$ => Standard file to open
   `* c$ => Pattern eg. Text (*.txt)|*.txt;*.bat|PureBasic (*.pb)|*.pb|DarkBasic (*.dba)|*.dba;*.dbpro|All files (*.*)|*.*
   `* a  => Patternposition 0 .. upto number of patterns

   `* param$ => Full Path+Filename

   LIB$ = "LIB_OPENFILEREQUEST"
   a$   = " "+chr$(34)+a$+chr$(34)   : `* Title
   b$   = " "+chr$(34)+b$+chr$(34)   : `* StandardFile
   c$   = " "+chr$(34)+c$+chr$(34)   : `* Pattern def: < All files (*.*)|*.* >
   d$   = " "+str$(a)                : `* PatternPosition def: < 0 >

   param$ = LIB_Thief(LIB$ + a$ + b$ + c$ + d$)

ENDFUNCTION param$

FUNCTION LIB_SaveFileRequest(a$,b$,c$,a)

   `* Open standard File Requester to save file
   `* -----------------------------------------
   `* a$ => Windowtitle
   `* b$ => Standard file to save
   `* c$ => Pattern eg. Text (*.txt)|*.txt;*.bat|PureBasic (*.pb)|*.pb|DarkBasic (*.dba)|*.dba;*.dbpro|All files (*.*)|*.*
   `* a  => Patternposition 0 .. upto Number of patterns

   `* param$ => Full Path+Filename

   LIB$ = "LIB_SAVEFILEREQUEST"
   a$   = " "+chr$(34)+a$+chr$(34)   : `* Title
   b$   = " "+chr$(34)+b$+chr$(34)   : `* StandardFile
   c$   = " "+chr$(34)+c$+chr$(34)   : `* Pattern def: < All files (*.*)|*.* >
   d$   = " "+str$(a)                : `* PatternPosition def: < 0 >

   param$ = LIB_Thief(LIB$ + a$ + b$ + c$ + d$)

ENDFUNCTION param$

FUNCTION LIB_PathRequest(a$,b$)

   `* Open standard Path Requester to select folder
   `* --------------------------------------------
   `* a$ => Infotext
   `* b$ => Initialpath eg. C:\

   `* param$ => Selected/Created path

   LIB$ = "LIB_PATHREQUEST"
   a$   = " "+chr$(34)+a$+chr$(34)   : `* Infotext
   b$   = " "+chr$(34)+b$+chr$(34)   : `* Initialpath:\

   param$ = LIB_Thief(LIB$ + a$ + b$)

ENDFUNCTION param$

FUNCTION LIB_InputRequest(a$,b$,c$)

   `* Open Windows Input Requester for stringinput
   `* --------------------------------------------
   `* a$ => Windowtitle
   `* b$ => Messagetext
   `* c$ => Given inputstring

   `* param$ => Inputstring

   LIB$ = "LIB_INPUTREQUEST"
   a$   = " "+chr$(34)+a$+chr$(34)   : `* Title
   b$   = " "+chr$(34)+b$+chr$(34)   : `* Message
   c$   = " "+chr$(34)+c$+chr$(34)   : `* Inputstring

   param$ = LIB_Thief(LIB$ + a$ + b$ + c$)

ENDFUNCTION param$

FUNCTION LIB_MessageRequest(a$,b$)

   `* Open simple Windows Mesage Requester
   `* ------------------------------------
   `* a$ => Windowtitle
   `* b$ => Message eg. new line by chr$(10)

   `* param = 1

   LIB$ = "LIB_MESSAGEREQUEST"
   a$   = " "+chr$(34)+a$+chr$(34)   : `* Title
   b$   = " "+chr$(34)+b$+chr$(34)   : `* Message

   param = val(LIB_Thief(LIB$ + a$ + b$))

ENDFUNCTION param

FUNCTION LIB_AskRequest(a$,b$)

   `* Open Windows Mesage Requester
   `* ------------------------------
   `* a$ => Windowtitle
   `* b$ => Message eg. new line by chr$(10)

   `* param = 1 for Yes - 0 for No/Cancel

   LIB$ = "LIB_ASKREQUEST"
   a$   = " "+chr$(34)+a$+chr$(34)   : `* Title
   b$   = " "+chr$(34)+b$+chr$(34)   : `* Message

   param = val(LIB_Thief(LIB$ + a$ + b$))-5

   if param <> 1 then param = 0

ENDFUNCTION param

FUNCTION LIB_ColorRequest

   `* Open Windows Color Requester
   `* ----------------------------

   `* param = Colorvalue

   LIB$ = "LIB_COLORREQUEST"

   param$ = LIB_Thief(LIB$)

   r = val( left$(param$,3) )
   g = val( mid$(param$,4) + mid$(param$,5) + mid$(param$,6) )
   b = val( right$(param$,3) )

   param = rgb(r,g,b)

ENDFUNCTION param

FUNCTION LIB_Thief(a$)

   `* Main Call for LIB_Thief
   `* Results will be copied into clipboardbuffer (helpneed tricky)
   `* -------------------------------------------------------------
   `* a$ => Commandline, params seperated by " "

   `* param$ = Resultstring

   execute file "LIB_Thief\LIB_Thief.exe",a$,"",1

   param$ = get clipboard$()

ENDFUNCTION param$