'-*----------------------------------------*-
' *                TIE V1.0a               * 
' *                                        * 
' *      Copyright ©1993 by Testaware      * 
' * Released ®02/08/93 by Volker Stepprath * 
'-*----------------------------------------*-
'
Close Workbench 
Request Off 
Break Off 
'
Dim XFELD$(47),XFELD(47),XHIGH$(9),XHIGH(9)
Global XFELD$(),XFELD(),XHIGH$(),XHIGH()
Global XMIN,XSEC,XTIE,XLEVEL,XPOINTS,XHIGH,XDEMO,XDEMO$,XMUS,XCONT,XCODE$
'
Unpack 16 To 0
Screen Hide 
Hide 
Track Loop On 
'
_GETBOBS
_INTRO
'
Do 
   _MENUE
   If XDEMO Then _DEMO Else _GAME
Loop 
'
Procedure _INTRO
   If Exist("tietopten")
      On Error Proc _FEHLER
      Resume Label _ERR
      Open In 1,"tietopten"
         For I=0 To 9
            Input #1,XHIGH$(I)
            Input #1,XHIGH(I)
         Next I
      _ERR:
      Close 1
   End If 
   Wait 100
   '
   Unpack 15 To 1
   Fade 2,,$FFF,$FFF,$FFF,$FFF,$FFF,$FFF,$FFF : Wait 30
   Fade 2,,$600,$800,$A20,$A40,$C60,$C80,$EC0 : Wait 200
   Fade 2,,$FFF,$FFF,$FFF,$FFF,$FFF,$FFF,$FFF : Wait 40
   Fade 2 : Wait 60 : Cls 0
   _TEXT["PRESENTS",129,8]
   _FADEIN : Wait 150
   _FADEOUT
End Proc
Procedure _MENUE
_MENUE:
   _SCREEN
   '
   Screen 0 : For I=1 To 31 : Colour I,$0 : Next I
   For I=16 To 23 : Colour I,$FFF : Next I
   '
   Screen 1 : For I=0 To 31 : Colour I,$0 : Next I
   _CREATEBACK
   Get Icon 0,1,0,64 To 179,109 : Make Icon Mask 
   Paste Icon 71,8,1
   Screen Display 1,128,138,,
   '
   Fade 1 To 0
   If XDEMO$="" Then Track Play 7 : XMUS=True
   XLEVEL=0
   Wait 15
   '
   Restore _TIEPALETTE
   Screen 0 : For I=16 To 23 : Read N : Colour I,N : Next I
   Screen 1 : Fade 2 To 0 : Wait 100
   Channel 0 To Screen Display 1
   Amal 0,"M 0,-96,48"
   Amal On 0
   While Chanmv(0) : Wend 
   Amal Off 
   '
   Restore _DEFPALETTE
   Screen 0 : For I=0 To 15 : Read N : Colour I,N : Next I
A: Screen 1 : _GOOD["A GAME BY VOLKER STEPPRATH",42,60]
   _GOOD["F1:.......START",93,94]
   _GOOD["F2:....PASSWORD",93,109]
   _GOOD["F3:...DEMO GAME",93,124]
   _GOOD["F4:.......MUSIC",93,139]
   _GOOD["F5:...HIGHSCORE",93,154]
   _GOOD["F6:.......RULES",93,169]
   _GOOD["F7:.....CREDITS",93,184]
   _GOOD["F8:....EXIT TIE",93,199]
   _GOOD["TIE  COPYRIGHT  1993  BY  TESTAWARE",2,235]
   Fade 3 To 0 : Wait 45
   Clear Key 
   '
   Do 
      If Key Shift=%11110100 Then _SHOWCODE : Goto _MENUE
      A$=Inkey$
      T=Scancode
      If T>0
         If T=80 : Rem * -F1 Start
            XPOINTS=0
            XCONT=3
            XDEMO=False
            XDEMO$=""
            Fade 2 : Wait 50
            Pop Proc
         End If 
         If T=81 : Rem * -F2 Password 
            _PASSWORD
         End If 
         If T=82 : Rem * -F3 Demo 
            XDEMO=True
            XDEMO$=""
            Fade 2 : Wait 50
            Pop Proc
         End If 
         If T=83 : Rem * -F4 Music
            If XMUS=False
               XMUS=True
               Track Play 7
            Else 
               XMUS=False
               Track Stop 
            End If 
         End If 
         If T=84 : Rem * -F5 Highscore
            _HIGHSCORE
            Goto A
         End If 
         If T=85 : Rem * -F6 Rules
            _RULES
            Goto A
         End If 
         If T=86 : Rem * -F7 Credits
            _CREDITS
            Goto A
         End If 
         If T=87 : Rem * -F8 Exit TIE 
            Erase 1
            Erase 2
            Fade 2,,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0 : Wait 50
            Amal 0,"M 0,96,48"
            Amal On 0
            While Chanmv(0) : Wend 
            Amal Off 
            '
            If XHIGH
               On Error Proc _FEHLER
               Resume Label _END
               Open Out 1,"tietopten"
                  For I=0 To 9
                     Print #1,XHIGH$(I)
                     Print #1,XHIGH(I)
                  Next I
               Close 1
               Wait 30
            End If 
            '
            _END: Wait 90
            Screen 0 : For I=0 To 31 : Colour I,$0 : Next I
            For I=16 To 23 : Colour I,$FFF : Next I
            Screen 1 : Fade 1 To 0 : Wait 15
            Fade 2 : Wait 50
            Track Stop 
            Request On 
            Wait 50
            End 
            _FEHLER: E=True : Resume Next 
         End If 
      End If 
   Loop 
'
_DEFPALETTE:
   Data $0,$EFF,$FFE,$244,$FFF,$888,$AA8,$466
   Data $400,$840,$A60,$C80,$EA0,$CCC,$EC4,$F0F
_TIEPALETTE:
   Data $200,$400,$840,$A60,$C80,$EA0,$CCC,$EC4
End Proc
Procedure _FEHLER
   Resume Label 
End Proc
Procedure _GAME
   Dim XRESET(47)
_START:
   '
   _LOADLEVEL
   For I=0 To 47
      XRESET(I)=XFELD(I)
   Next I
   '
   X=0 : Y=0 : XALT=0 : YALT=0
   '
   Every 50 Proc _TIME
   Every On 
   '
   Do 
      T=0
      Clear Key 
      While Joy(1)=16 : Wend 
      While T=0
         Exit If XMIN=0 and XSEC=0,2
         T=Joy(1)
         Exit If T
         T=Asc(Upper$(Inkey$))
         Exit If T
      Wend 
      '
      If Y>0 and(T=1 or T=5 or T=9 or T=30) : Dec Y : _MOVE[0,-37] : End If 
      If Y<5 and(T=2 or T=6 or T=10 or T=31) : Inc Y : _MOVE[0,37] : End If 
      If X>0 and(T=4 or T=5 or T=6 or T=29) : Dec X : _MOVE[-37,0] : End If 
      If X<7 and(T=8 or T=9 or T=10 or T=28) : Inc X : _MOVE[37,0] : End If 
      '
      If T=27 Then Exit 
      If T=42 Then XOK=True : Exit 
      If T=77
         If XMUS=True
            XMUS=False
            Track Stop 
         Else 
            XMUS=True
            Track Play 7
         End If 
      End If 
      If T=80 Then _PAUSE
      If T=82
         For I=0 To 47
            XFELD(I)=XRESET(I)
            If XFELD(I)>0
               A=I mod 8 : B=I/8
               Paste Bob A*37+22,B*37+12,XFELD(I)
            End If 
         Next I
      End If 
      '
      N=X+Y*8
      '
      If XFELD(N)>0 and(T=16 or T=32)
         If XFELD(N)=1
            XFELD(N)=2
         Else 
            XFELD(N)=1
         End If 
         _BOBOFF
         Paste Bob X*37+22,Y*37+12,XFELD(N)
         _TURNTOO[N,1]
         Bob 10,X*37+20,Y*37+10,10
         '
         '* Level gelößt ? -------------------------
         XOK=True
         For I=0 To 47
            If XFELD(I)>1 : XOK=False : I=47 : End If 
         Next I
         Exit If XOK
         '* ----------------------------------------- 
      End If 
   Loop 
   '
   Every Off 
   Wait 50
   _BOBOFF
   Flash Off 
   If XMIN=0 and XSEC=0 : Rem * Time out 
      _SCRLDOWN
      _SCRLLEFT["TIME OUT",183]
      T=27
   End If 
   If XOK
      _SCRLDOWN
      _SCRLLEFT["LEVEL COMPLETED",215]
   End If 
   Screen 1 : Fade 2 : Wait 30
   Screen 2 : Fade 2 : Wait 30
   Screen 1
   Anim Off 
   Bob Off 
   If XOK Then _GETPOINTS
   '
   If XLEVEL=46 and T<>27
      _RECOMMEND
      XOK=False
      XCONT=0
   End If 
   '
   If XOK Then XOK=False : Goto _START
   '
   If XCONT>0
      _SCREEN
      _TEXT["CONTINUES"+Str$(XCONT),108,105]
      _TEXT["RESTART THE LAST LEVEL Y/N",40,125]
      _FADEIN
      N$=Input$(1)
      If Upper$(N$)="Y"
         Dec XCONT
         Dec XLEVEL
         _FADEOUT
         Goto _START
      End If 
      _FADEOUT
   End If 
   '
   If XPOINTS>XHIGH(9) Then _ENTERHIGH
End Proc
Procedure _DEMO
   Randomize Timer
   XLEVEL=Rnd(45)
   _LOADLEVEL
   '
   L=Len(XDEMO$)
   '
   For I2=1 To L
      N=Asc(Mid$(XDEMO$,I2,1))-65
      X=N mod 8 : Y=N/8
      '
      If XALT<X
         For I=XALT To X-1 : _MOVE[37,0] : Next I
      End If 
      If XALT>X
         For I=X To XALT-1 : _MOVE[-37,0] : Next I
      End If 
      If YALT<Y
         For I=YALT To Y-1 : _MOVE[0,37] : Next I
      End If 
      If YALT>Y
         For I=Y To YALT-1 : _MOVE[0,-37] : Next I
      End If 
      '
      XALT=X : YALT=Y
      '
      If XFELD(N)>0
         If XFELD(N)=1
            XFELD(N)=2
         Else 
            XFELD(N)=1
         End If 
         _BOBOFF
         Paste Bob X*37+22,Y*37+12,XFELD(N) : Wait Vbl 
         _TURNTOO[N,1]
         Bob 10,X*37+20,Y*37+10,10 : Wait 10
      End If 
      If Asc(Inkey$)=27 Then I2=L
   Next I2
   '
   Wait 50
   _BOBOFF
   _SCRLDOWN
   _SCRLLEFT["DEMO OVER",190]
   Flash Off 
   Screen 1 : Fade 2 : Wait 30
   Screen 2 : Fade 2 : Wait 30
   Screen 1
   Anim Off 
   Bob Off 
End Proc
Procedure _PAUSE
   Every Off 
   Flash Off 
   _BOBOFF
   Fade 2
   _SCRLDOWN
   _SCRLLEFT["PAUSED",175]
   _SCRLDOWN
   If XMIN<10 : XMIN$="0" : End If 
   If XSEC<10 : XSEC$="0" : End If 
   If XLEVEL<10 : XLEV$="0" : End If 
   A$=" 00000" : Right$(A$,Len(Str$(XPOINTS))-1)=Str$(XPOINTS)-" "
   N$="TIME "+XMIN$+Str$(XMIN)-" "+":"+XSEC$+Str$(XSEC)-" "
   N$=N$+"  LEVEL "+XLEV$+Str$(XLEVEL)-" "+"  POINTS "+A$-" "
   _TEXT2[N$,6,8]
   Fade 2 To -1 : Wait 30
   Flash 15,"(121,3)(232,3)(343,3)(454,3)(565,5)(454,4)(343,4)(232,3)"
   Every 50 Proc _TIME
   Every On 
End Proc
Procedure _MOVE[X,Y]
   Amal 2,"M"+Str$(X)+","+Str$(Y)+",9"
   Amal On 2
   While Chanmv(2) : Wend 
End Proc
Procedure _BOBOFF
   For I=0 To 4
      Bob Off 10+I
   Next I
   Wait Vbl 
End Proc
Procedure _SCREEN
   Screen Open 1,320,256,32,Lowres
   Flash Off 
   Curs Off 
   Cls 0
   For I=0 To 31
      Colour I,$0
   Next I
End Proc
Procedure _ENTERHIGH
   _SCREEN
   _TEXT["CONGRATULATION",96,70]
   _TEXT["YOU ENTERED THE TOP 10 CHARTS",28,85]
   _TEXT["PLEASE TYPE IN YOUR NAME",52,100]
   _TEXT["...................",75,140]
   _FADEIN
   Repeat 
      N=0 : Clear Key 
      While N=0 : N=Asc(Upper$(Inkey$)) : Wend 
      If(N>64 and N<91) or N=32
         If Len(N$)<19 : N$=N$+Chr$(N) : End If 
      End If 
      If N=8
         N$=Left$(N$,Len(N$)-1)
      End If 
      _TEXT[N$+String$(".",19-Len(N$)),75,140]
   Until N=13
   '
   XHIGH$(9)=N$
   XHIGH(9)=XPOINTS
   '
   For I=0 To 8
      For I2=I+1 To 9
         If XHIGH(I2)>XHIGH(I)
            Swap XHIGH(I),XHIGH(I2)
            Swap XHIGH$(I),XHIGH$(I2)
         End If 
      Next I2
   Next I
   '
   XHIGH=True : Rem * Highscore speichern
   _FADEOUT
End Proc
Procedure _GETPOINTS
   If XMIN<10 Then XMIN$="0"
   If XSEC<10 Then XSEC$="0"
   A$=" 00000" : Right$(A$,Len(Str$(XPOINTS))-1)=Str$(XPOINTS)-" "
   '
   _SCREEN
   _TEXT["TIME   X   BONUS   =   POINTS",26,108]
   _TEXT[XMIN$+Str$(XMIN)-" "+":"+XSEC$+Str$(XSEC)-" ",23,126]
   _TEXT["10",139,126]
   _TEXT[A$-" ",239,126]
   _FADEIN : Wait 30
   '
   If XMIN>0
      N=XMIN
      For I=1 To N
         Dec XMIN
         Add XPOINTS,600
         If XMIN<10 : XMIN$="0" : End If 
         A$=" 00000" : Right$(A$,Len(Str$(XPOINTS))-1)=Str$(XPOINTS)-" "
         _TEXT[XMIN$+Str$(XMIN)-" ",23,126]
         _TEXT[A$-" ",239,126]
         Wait 10
      Next I
   End If 
   If XSEC>0
      N=XSEC
      For I=1 To N
         Dec XSEC
         Inc XPOINTS
         If XSEC<10 : XSEC$="0" : End If 
         A$=" 00000" : Right$(A$,Len(Str$(XPOINTS))-1)=Str$(XPOINTS)-" "
         _TEXT[XSEC$+Str$(XSEC)-" ",50,126]
         _TEXT[A$-" ",239,126]
         Wait Vbl 
      Next I
   End If 
   '  
   _WAIT
   _FADEOUT
End Proc
Procedure _RECOMMEND
   _SCREEN
   For I=0 To 6
      Read N$
      _TEXT[N$,160-(Len(N$)*9)/2,75+I*15]
   Next I
   _FADEIN : _WAIT : _FADEOUT
   '
   Data "YOU ARE A FANTASTIC COMBINATIONER"
   Data "CAUSE THERE IS NO LEVEL LEFT WHICH"
   Data "YOU WERE NOT ABLE TO CRACK"
   Data "SO I RECOMMEND TO HAVE A LOOK OUT"
   Data "FOR KASPAROV TO BEAT HIM IN CHESS"
   Data " "
   Data "I KNOW YOU COULD DO IT!"
End Proc
Procedure _SCRLDOWN
   Screen 2
   Def Scroll 1,7,7 To 314,17,0,1
   For I=0 To 11
      Scroll 1 : Wait 3
   Next I
   Screen 1
End Proc
Procedure _SCRLLEFT[N$,N]
   Screen 2
   Def Scroll 1,7,7 To 314,17,-1,0
   L=Len(N$)+1
   For I=1 To N
      Add A,1,0 To 8 : Scroll 1
      If Fire(1)=0 Then Wait Vbl 
      If A=8
         If B<L
            Inc B
            _TEXT2[Mid$(N$,B,1),304,8]
         End If 
      End If 
   Next I
   _WAIT
   Screen 1
End Proc
Procedure _WAIT
   Wait 30
   Clear Key 
   While Mouse Key=0 and Asc(Inkey$)=0 and Fire(1)=0 : Wend 
End Proc
Procedure _TURNTOO[N,S]
   L=Len(XFELD$(N))
   A$=XFELD$(N)
   '
   If S and XMUS=False
      Sam Play 1,1,21000
   End If 
   '
   For I=1 To L
      N=Asc(Mid$(A$,I,1))-65
      If XFELD(N)=1
         XFELD(N)=2
      Else 
         XFELD(N)=1
      End If 
      X=N mod 8
      Y=N/8
      Paste Bob X*37+22,Y*37+12,XFELD(N)
      If S
         Bob 10+I,X*37+20,Y*37+10,10
      End If 
   Next I
End Proc
Procedure _SHAKEIT
   For I=1 To XLEVEL
      N=Rnd(47)
      If N<>NALT and XFELD(N)>0
         NALT=N
         If XFELD(N)>0
            If XFELD(N)=1
               XFELD(N)=2
            Else 
               XFELD(N)=1
            End If 
            X=N mod 8 : Y=N/8
            XDEMO$=XDEMO$+Chr$(65+N)
            Paste Bob X*37+22,Y*37+12,XFELD(N)
            _TURNTOO[N,0]
         End If 
      Else 
         Dec I
      End If 
   Next I
   _BOBOFF
End Proc
Procedure _LOADLEVEL
   _SCREEN
   '
   For I=0 To 47
      XFELD(I)=0
      XFELD$(I)=""
   Next I
   '
   Inc XLEVEL
   '
   N=XLEVEL*8+25
   XMIN=N/60
   XSEC=N mod 60
   If XLEVEL<7
      XTIE=2
   Else 
      XTIE=4
   End If 
   '
   Randomize Timer
   For I=1 To XLEVEL+2
      N=Rnd(47)
      If XFELD(N)=0
         XFELD(N)=1
      Else 
         Dec I
      End If 
   Next I
   '
   If XDEMO=False
      If XLEVEL<10 : XLEV$="0" : End If 
      N$="PREPARE FOR LEVEL "+XLEV$+Str$(XLEVEL)-" "
      _TEXT[N$,160-(Len(N$)*9)/2,110]
      _GETCODE[""] : _TEXT[XCODE$,160-(Len(XCODE$)*9)/2,130]
      _FADEIN : _WAIT : _FADEOUT
   End If 
   '
   _CREATEBACK
   Screen Open 2,320,36,16,Lowres
   Screen Hide 
   Screen Display 2,,266,,
   Flash Off 
   Cls 0
   For I=1 To 31 : Colour I,$0 : Next I
   Screen Copy 0,0,40,320,64 To 2,0,0
   Screen Show 
   '
   If XDEMO=False
      If XMIN<10 : XMIN$="0" : End If 
      If XSEC<10 : XSEC$="0" : End If 
      A$=" 00000" : Right$(A$,Len(Str$(XPOINTS))-1)=Str$(XPOINTS)-" "
      N$="TIME "+XMIN$+Str$(XMIN)-" "+":"+XSEC$+Str$(XSEC)-" "
      N$=N$+"  LEVEL "+XLEV$+Str$(XLEVEL)-" "+"  POINTS "+A$-" "
      _TEXT2[N$,6,8]
   Else 
      _TEXT2["DEMO",142,8]
   End If 
   '
   Screen 1
   For I=0 To 5
      For I2=0 To 7
         If XFELD(A)=1
            Paste Bob 22+I2*37,12+I*37,1
         End If 
         Inc A
      Next I2
   Next I
   '
   _MAKETIES
   _SHAKEIT
   '
   Flash 15,"(121,3)(232,3)(343,3)(454,3)(565,5)(454,4)(343,4)(232,3)"
   '
   Double Buffer 
   '
   Channel 1 To Bob 3
   Channel 2 To Bob 3
   Bob 3,30,19,3
   Anim 1,"(3,4)(4,4)(5,4)(6,4)(7,4)(8,4)(9,4)(8,4)(7,4)(6,4)(5,4)(4,4)L"
   Anim On 1
   '
   Screen 2 : Fade 2 To -1 : Wait 30
   Screen 1 : Fade 2 To -1 : Wait 30
   '
End Proc
Procedure _MAKETIES
   For I=0 To 5
      For I2=0 To 7
         If XFELD(N)=1
            TIE=Rnd(XTIE) : Rem * # der VerknÜpfungen
            TIE=Max(1,TIE)
            For II=1 To TIE
               A=Rnd(47)
               If A<>N and XFELD(A)=1
                  N$=Chr$(65+A)
                  If Instr(XFELD$(N),N$)=0
                     XFELD$(N)=XFELD$(N)+N$ : Rem * Welche Kugeln mitdrehen
                  Else 
                     Dec II
                  End If 
               Else 
                  Dec II
               End If 
            Next II
         End If 
         Inc N
      Next I2
   Next I
End Proc
Procedure _GETBOBS
   Get Bob 1,203,0 To 218,15 : Hot Spot 1,$11
   Get Bob 2,218,0 To 233,15 : Hot Spot 2,$11
   '
   Get Bob 3,180,65 To 211,97 : Hot Spot 3,$11
   Get Bob 4,212,65 To 243,97 : Hot Spot 4,$11
   Get Bob 5,244,65 To 275,97 : Hot Spot 5,$11
   Get Bob 6,276,65 To 307,97 : Hot Spot 6,$11
   Get Bob 7,180,99 To 211,130 : Hot Spot 7,$11
   Get Bob 8,212,99 To 243,130 : Hot Spot 8,$11
   Get Bob 9,244,99 To 275,130 : Hot Spot 9,$11
   '
   Get Bob 10,233,0 To 252,19
End Proc
Procedure _CREATEBACK
   Cls 0
   Dim X1(6)
   Dim X2(6)
   Restore 
   For I=0 To 6
      Read X1(I),X2(I)
   Next I
   '
   Randomize Timer
   For Y=0 To 15
      X=0
      For I=0 To 12
         N=Rnd(6)
         Screen Copy 0,X1(N),0,X2(N),15 To 1,X,Y*16
         Add X,X2(N)-X1(N)+1
      Next I
   Next Y
   '
   Data 2,31
   Data 32,66
   Data 67,91
   Data 92,115
   Data 116,140
   Data 141,171
   Data 172,202
End Proc
Procedure _TIME
   Dec XSEC
   If XSEC<0
      Dec XMIN : XSEC=59
   End If 
   If XMIN<10 Then XMIN$="0"
   If XSEC<10 Then XSEC$="0"
   _TEXT2[XMIN$+Str$(XMIN)-" "+":"+XSEC$+Str$(XSEC)-" ",51,8]
   Every On 
End Proc
Procedure _FADEIN
   Fade 1,,,,,,,,,$FFF,$FFF,$FFF,$FFF,$FFF,$FFF,$FFF : Wait 15
   Fade 2 To -1 : Wait 30
End Proc
Procedure _FADEOUT
   Fade 1,,,,,,,,,$FFF,$FFF,$FFF,$FFF,$FFF,$FFF,$FFF : Wait 15
   Fade 2 : Wait 30
End Proc
Procedure _PASSWORD
   Screen Open 2,320,36,16,Lowres
   Screen Hide 
   Cls 0
   Flash Off 
   For I=1 To 15 : Colour I,$0 : Next I
   Screen Copy 0,0,40,320,64 To 2,0,0
   _TEXT2["ENTER PASSWORD:",6,8]
   Screen Display 2,,298,,
   Screen Show 2
   Channel 1 To Screen Display 2
   Amal 1,"M 0,-32,32"
   Fade 4 To -1
   Amal On 1
   While Chanmv(1) : Wend 
   Amal Off 
   '
   Repeat 
      N=0 : Clear Key 
      While N=0 : N=Asc(Upper$(Inkey$)) : Wend 
      If Len(N$)<17 and N>31 : N$=N$+Chr$(N) : End If 
      If N=8
         N$=Left$(N$,Len(N$)-1)
      End If 
      _TEXT2[N$+" ",150,8]
   Until N=13
   '
   If N$<>"" Then XLEVEL=0 : _GETCODE[N$]
   '
   Amal 1,"M 0,32,32"
   Fade 4
   Amal On 1
   While Chanmv(1) : Wend 
   Screen Close 2
End Proc
Procedure _SHOWCODE
   Fade 2 : Wait 30
   _CREATEBACK
   _GOOD["ALL LEVELCODES OF TIE",66,13]
   XLEVEL=0
   For I=0 To 1
      For I2=1 To 23
         Inc XLEVEL
         _GETCODE[""]
         If XLEVEL<10 Then N$="0" Else N$=""
         _GOOD[N$+Str$(XLEVEL)-" "+"."+XCODE$+String$(".",11-Len(XCODE$)),I*150+22,I2*8+29]
      Next I2
   Next I
   _GOOD["PRESS THE STAR TO SKIP A LEVEL!",21,235]
   Fade 2 To -1 : Wait 30
   _WAIT
   Fade 2 : Wait 30
   XDEMO$=" "
End Proc
Procedure _GETCODE[N$]
   If N$<>""
      For I=1 To 46
         Read XCODE$
         If XCODE$=N$ : XLEVEL=I-1 : I=46 : End If 
      Next I
   Else 
      For I=1 To XLEVEL
         Read XCODE$
      Next I
   End If 
   '
   Data "","NIRVANA","KRUEMMEL","NACHTROCK","METALLICA","HECHIZO","VENOM"
   Data "HEADBANGER","ONCE","PICASSO","PINBALL","SEPULTURA","NIGHTMARE","JUDITH"
   Data "ATOMIX","HAUNFUENWER","PSYGNOSIS","SPHERIX","TESTAMENT","ZAPPA"
   Data "BOHNENSUPPE","HORRORSCOPE","DADADA","SANCTUARY","HAIFISCHE","SUNSHINE"
   Data "DELUXE","BLUEPERIODE","COCACOLA","RITUAL","PARTYTIME","DATAGROOVE","SHANANA"
   Data "BEAST","PEARLJAM","ALBUNDY","HALIME","DOORS","TATTOO","STRIPPED"
   Data "LAVIE","OVERKILL","QUEENSRYCHE","GOLDRAUSCH","CIRCUS","GODS"
End Proc
Procedure _HIGHSCORE
   '* This programming looks like crazy ! 
   Fade 2 : Wait 30
   _CREATEBACK
   Get Icon 0,1,0,64 To 179,109 : Make Icon Mask 
   Paste Icon 71,8,1
   _GOOD["THE TOP 10 RANKING OF TIE",46,60]
   For I=0 To 9
      A$=" 00000" : Right$(A$,Len(Str$(XHIGH(I)))-1)=Str$(XHIGH(I))-" "
      Inc B
      If B<10 Then B$="0" Else B$=""
      _GOOD[B$+Str$(B)-" "+"."+XHIGH$(I)+String$(".",22-Len(XHIGH$(I)))+A$-" ",25,85+I*12]
   Next I
   _GOOD["TIE  COPYRIGHT  1993  BY  TESTAWARE",2,235]
   Fade 3 To 0 : _WAIT
   Fade 2 : Wait 30
   _CREATEBACK
   Get Icon 0,1,0,64 To 179,109 : Make Icon Mask 
   Paste Icon 71,8,1
End Proc
Procedure _RULES
   Fade 2 : Wait 30
   _CREATEBACK
   _GOOD["THE VERY SHORT GAMERULES OF TIE",21,19]
   For I=1 To 17
      Read N$
      _GOOD[N$,160-((Len(N$)*9)/2),40+I*11]
   Next I
   Fade 3 To 0 : _WAIT
   Fade 2 : Wait 30
   _CREATEBACK
   Get Icon 0,1,0,64 To 179,109 : Make Icon Mask 
   Paste Icon 71,8,1
   Data "AT THE BEGINNING OF THE GAME TIE"
   Data "YOU WILL SEE A FIELD WITH 3 UPTO"
   Data "48 BALLS. SOME OF THESE BALLS ARE"
   Data "COPPER COLOURED THE REST SHOULD"
   Data "BE IN COLOUR SILVER. THE AIM FOR"
   Data "YOU IS TO TURN ALL COPPER BALLS"
   Data "BY SELECTING WITH THE JOYSTICK IN"
   Data "SILVER BALLS. BUT IT IS NOT DONE"
   Data "WITH SIMPLY TURNING. EVERY BALL"
   Data "HAS ITS OWN INDIVIDUAL COMBINATION"
   Data "WITH SOME OTHER BALLS. SO IF YOU"
   Data "TURN A BALL IT WILL TURN ONE UPTO"
   Data "A MAXIMUM OF FOUR BALLS TOO."
   Data "THE PLAYED LEVEL IS COMPLETED IF"
   Data "ALL BALLS ARE SILVER COLOURED."
   Data "SHORTCUTS DURING GAME:"
   Data "M=MUSIC R=RESET P=PAUSE ESC=ABORT"
End Proc
Procedure _CREDITS
   Fade 2 : Wait 30
   _CREATEBACK
   For I=1 To 19
      Read N$
      _GOOD[N$,160-((Len(N$)*9)/2),13+I*11]
   Next I
   Fade 3 To 0 : _WAIT
   Fade 2 : Wait 30
   _CREATEBACK
   Get Icon 0,1,0,64 To 179,109 : Make Icon Mask 
   Paste Icon 71,8,1
   Data "AMOS/ACMP......FRANCOIS LIONET"
   Data "TESTING..........KARSTEN BLANK"
   Data "PROGRAMMING...VOLKER STEPPRATH"
   Data "",""
   Data "NOTE:"
   Data "TIE IS PUBLIC DOMAIN! BUT IF YOU"
   Data "REAL LIKE THIS GAME I WANT TO BEG"
   Data "FOR SOMETHING: PLEASE SEND ME A"
   Data "POSTCARD WITH GREETINGS. THATS ALL!"
   Data "I THINK THAT IS NOT TO MUCH AGAINST"
   Data "THE SPARE TIME I SPEND IN MAKING"
   Data "OF TIE. SO PLEASE WRITE TO:"
   Data ""
   Data "VOLKER STEPPRATH - TEGELERSTR.7"
   Data "40789 MONHEIM - GERMANY"
   Data "",""
   Data "THANKS FOR PLAYING THIS GAME!"
End Proc
Procedure _TEXT2[N$,X,Y]
   T$="ABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789.:!=+-/? "
   '
   L=Len(N$)
   '
   For I=1 To L
      A$=Mid$(N$,I,1)
      A=Instr(T$,A$)
      If A>0
         If A<32 : B=20 Else B=30 : Add A,-31 : End If 
         Screen Copy 0,(A-1)*10+1,B,A*10,B+9 To 2,X,Y
      End If 
      Add X,9
   Next I
End Proc
Procedure _TEXT[N$,X,Y]
   T$="ABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789.:!=+-/? "
   '
   L=Len(N$)
   '
   For I=1 To L
      A$=Mid$(N$,I,1)
      A=Instr(T$,A$)
      If A>0
         If A<32 : B=20 Else B=30 : Add A,-31 : End If 
         Screen Copy 0,(A-1)*10+1,B,A*10,B+9 To 1,X,Y
      End If 
      Add X,9
   Next I
End Proc
Procedure _GOOD[N$,X,Y]
   T$="ABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789.:!=+-/? "
   '
   L=Len(N$)
   '
   For I=1 To L
      A$=Mid$(N$,I,1)
      A=Instr(T$,A$)
      If A>0
         If A<32 : B=20 Else B=30 : Add A,-31 : End If 
         Get Icon 0,1,(A-1)*10+1,B To A*10,B+9
         Make Icon Mask 1
         Paste Icon X,Y,1
      End If 
      Add X,9
   Next I
End Proc