'
'             -*- COLORIX -*-
'
'  written by Volker Stepprath 20/01/93
'
'       Colorix © 1993 by Testaware
'
'
Close Workbench 
Request Off 
Break Off 
'
Dim FELD(20,20),KLEINFELD(8,8),HNAME$(8),HSCORE(8)
Global FELD(),KLEINFELD(),HNAME$(),HSCORE(),LEVEL,PUNKTE,FFCF,TM,TS
Global LEVELMAX,BACK,HOCH,BREIT,CODE$,CHECKOK,EINTRAGEN,CONTINUE,MUSE
'
_INSTALLGFX
_INTRO
'
Channel 1 To Bob 10
Channel 2 To Bob 10
Channel 4 To Bob 14
Channel 5 To Rainbow 0
'
Do 
  If CHECKOK=True
    _LOAD
    _SPIELFELD
    _STEUERUNG
    '
    If CHECKOK=True and(TM>0 or TS>0)
      _GETBALLS
    End If 
    '
    Wait 10 : Fade 2 : Wait 30
    '
    If LEVEL=LEVELMAX and CHECKOK=True
      _ALLDONE
      CHECKOK=False
    End If 
    '  
    If PUNKTE>HSCORE(8) and CHECKOK=False : _EINTRAGEN : End If 
  End If 
  '
  If CHECKOK=False
    _MENU
  End If 
Loop 
'
Procedure _MENU
  Screen Open 1,320,256,16,Lowres
  Screen Hide 
  Flash Off 
  Pen 1 : Paper 0 : Curs Off 
  For I=0 To 16 : Colour I,$0 : Next I
  Cls 0
  CHECKOK=True
  LEVEL=0
  PUNKTE=0
  CONTINUE=3
MENU:
  Screen Copy 0,87,83,296,111 To 1,55,20
  _TEXT[120,78,"START"]
  _TEXT[92,98,"HIGHSCORE"]
  _TEXT[120,118,"MUSIC"]
  _TEXT[78,138,"INFORMATION"]
  _TEXT[113,158,"FINITO"]
  _TEXT[20,230,"©1993 by testaware"]
  Screen Show 1
  Fade 2,,$FFF,$FFF,,$900,$C00,$F00,$70,$A1,$F0,$D91,$EC1,$FF0,$A,$C,$F
  Set Rainbow 0,0,30,"","","(1,1,15)(1,-1,15)"
  Rainbow 0,0,110,32
  Wait 30
  Y=1
  Do 
    If Inkey$<>""
      N=Scancode
      If N=95 and Key Shift=2
        Locate 10,25 : Line Input "ENTER STARTLEVEL:";N$
        Locate 0,25 : Print Space$(80)
        LEVEL=Val(N$)
        Dec LEVEL
        LEVEL=Min(LEVEL,LEVELMAX-1)
        LEVEL=Max(0,LEVEL)
      End If 
    End If 
    '
    J=Joy(1)
    If J<>0
      If J=1 and Y>1
        Dec Y : Rainbow 0,0,90+Y*20,32 : Wait 10
      End If 
      If J=2 and Y<5
        Inc Y : Rainbow 0,0,90+Y*20,32 : Wait 10
      End If 
      If J=16
        If Y=1
          Rainbow 0,0,0,0
          Fade 2 : Wait 40
          Pop Proc
        End If 
        '
        If Y=2
          _HIGHSCORE
          Goto MENU
        End If 
        '
        If Y=3 and FFCF
          If MUSE=True
            MUSE=False
            Music Off 
          Else 
            MUSE=True
            Music 1
          End If 
          Wait 50
          While Fire(1)=True : Wend 
        End If 
        '
        If Y=4
          _INFORMATION
          Goto MENU
        End If 
        If Y=5
          If EINTRAGEN
            On Error Goto _END
            Open Out 1,"colorixhigh"
              For I=0 To 8
                Print #1,HNAME$(I)
                Print #1,HSCORE(I)
              Next I
            Close 1
          End If 
        _END:
          Rainbow 0,0,0,0
          Fade 3
          If MUSE=True
            For I=63 To 0 Step -1
              Mvolume I : Wait 2
            Next I
          End If 
          Wait 150
          Amos To Back 
          Erase 1
          Erase 2
          Screen Close 0
          Screen Close 1
          Request On 
          Wait Vbl 
          End 
        End If 
        '
      End If 
    End If 
  Loop 
End Proc
Procedure _HIGHSCORE
  Rainbow 0,0,0,0
  Fade 2 : Wait 40
  Cls 0
  Screen Copy 0,87,112,296,126 To 1,25,20
  Screen Copy 0,87,127,145,141 To 1,234,20
  For I=0 To 8
    N$=""
    If HSCORE(I)<100000 Then N$="0"
    If HSCORE(I)<10000 Then N$="00"
    If HSCORE(I)<1000 Then N$="000"
    If HSCORE(I)<100 Then N$="0000"
    If HSCORE(I)<10 Then N$="00000"
    N$=N$+Str$(HSCORE(I))-" "
    _TEXT[0,I*15+55,Str$(I+1)-" "+"."]
    _TEXT[38,I*15+55,HNAME$(I)]
    _TEXT[231,I*15+55,N$]
  Next I
  _TEXT[20,230,"©1993 by testaware"]
  '
  Set Rainbow 0,1,30,"(1,1,15)(1,-1,15)","(1,1,15)(1,-1,15)",""
  Rainbow 0,0,57,173
  Amal 5,"Loop: M 0,38,100; M 0,-38,100; J Loop"
  Amal On 5
  '
  Fade 2,,$FFF,$FFF,,$900,$C00,$F00,$70,$A1,$F0,$D91,$EC1,$FF0,$A,$C,$F
  Wait 40
  While Fire(1)=False : Wend 
  '
  Amal Off 
  Fade 2
  Set Rainbow 0,0,30,"","",""
  Rainbow 0,0,0,0
  Wait 40
  Cls 0
End Proc
Procedure _INFORMATION
  Rainbow 0,0,0,0
  Fade 2,,$0 : Wait 30
  Ink 0 : Bar 0,60 To 320,256
  _TEXT[0,68,"to play colorix you"]
  _TEXT[0,85,"simply have to select"]
  _TEXT[0,102,"one coloured ball"]
  _TEXT[0,119,"in the playfield"]
  _TEXT[0,136,"by pressing the"]
  _TEXT[0,153,"firebutton and move"]
  _TEXT[0,170,"the ball in any way."]
  _TEXT[0,187,"but do not forget"]
  _TEXT[0,204,"that the moved ball"]
  _TEXT[0,221,"only stops when"]
  Fade 2,,$FFF : Wait 30
  While Fire(1)=False : Wend 
  Fade 2,,$0 : Wait 30
  '
  Bar 0,60 To 320,256
  _TEXT[0,68,"there is a hindrance"]
  _TEXT[0,85,"in its way. a level"]
  _TEXT[0,102,"is completed when"]
  _TEXT[0,119,"the given arrangement"]
  _TEXT[0,136,"of balls is created !"]
  _TEXT[0,162,"shortcuts during game"]
  _TEXT[0,179,"m = music on / off"]
  _TEXT[0,196,"p = pause"]
  _TEXT[0,213,"q = abort"]
  _TEXT[0,230,"r = restart level"]
  Fade 2,,$FFF : Wait 30
  While Fire(1)=False : Wend 
  Fade 2,,$0 : Wait 30
  '
  Bar 0,60 To 320,256
  _TEXT[0,68,"colorix is written in"]
  _TEXT[0,85,"amos v1.3 / acmp v1.0"]
  _TEXT[0,102,"and of course p.d. !"]
  _TEXT[0,119,"for critics or tips"]
  _TEXT[0,136,"contact me at:"]
  _TEXT[0,170,"VOLKER STEPPRATH"]
  _TEXT[0,187,"SPANDAUERSTR.4"]
  _TEXT[0,204,"4019 / MONHEIM"]
  _TEXT[0,221,"GERMANY"]
  Fade 2,,$FFF : Wait 30
  While Fire(1)=False : Wend 
  Fade 2,,$0 : Wait 30
  Bar 0,60 To 320,256
End Proc
Procedure _STEUERUNG
  Clear Key 
  '
  Every 50 Proc _ZEIT
  Every On 
  '
  Do 
    '
    If Inkey$<>""
      N=Scancode
      Clear Key 
      If N=19
        Every Off 
        Fade 2 : Wait 30
        TM2=TM : TS2=TS
        Dec LEVEL
        Add PUNKTE,-PUNKTE/5
        _LOAD
        TM=TM2 : TS=TS2
        _SPIELFELD
        XM=0 : YM=0
        Every 50 Proc _ZEIT
        Every On 
      End If 
      If N=25
        Every Off 
        _PAUSE
        Every 50 Proc _ZEIT
        Every On 
      End If 
      If N=55 and FFCF
        If MUSE=True
          MUSE=False : Music Off 
        Else 
          MUSE=True : Music 1
        End If 
      End If 
      If N=16 : Every Off : TM=0 : TS=0 : End If 
      If N=95 and Key Shift=2 : Every Off : CHECKOK=True : Pop Proc : End If 
    End If 
    If TM=0 and TS=0 Then Every Off : _CONTINUE : Pop Proc
    '
    J=Joy(1)
    If J<16
      If(J=1 or J=5 or J=9) and YM>0
        Dec YM
        Y=-11
      End If 
      If(J=2 or J=6 or J=10) and YM<20
        Inc YM
        Y=11
      End If 
      If(J=4 or J=5 or J=6) and XM>0
        Dec XM
        X=-11
      End If 
      If(J=8 or J=10 or J=9) and XM<20
        Inc XM
        X=11
      End If 
      Amal 4,"M"+Str$(X)+","+Str$(Y)+",4"
      Amal On 4
      While Chanmv(4) : Wend 
      X=0 : Y=0
    End If 
    '
    If J=16
      If FELD(XM,YM)>3
        '
        Bob 10,XM*11+88,YM*11,10
        Amal 1,"A 0,(10,2)(11,2)(12,2)(13,2)"
        Amal On 1
        '
        If MUSE=False
          Sam Loop On 
          Sam Play 1,3,20000
        End If 
        '
        Repeat 
          FJ=Joy(1)
          If FJ>16
            Add FJ,-16 : I=False
            If FJ=1 and FELD(XM,YM-1)=1 : _HOCH[XM,YM] : I=True : End If 
            If FJ=2 and FELD(XM,YM+1)=1 : _RUNTER[XM,YM] : I=True : End If 
            If FJ=4 and FELD(XM-1,YM)=1 : _LINKS[XM,YM] : I=True : End If 
            If FJ=8 and FELD(XM+1,YM)=1 : _RECHTS[XM,YM] : I=True : End If 
            If I
              _CHECK
              If CHECKOK
                Every Off 
                Amal Off 1 : Bob Off 10
                If MUSE=False : Sam Loop Off : End If 
                Pop Proc
              End If 
            End If 
            Exit If I=True
          End If 
        Until FJ=False
        '
        Amal Off 1
        Bob Off 10
        '
        If MUSE=False : Sam Loop Off : End If 
        '
      End If 
    End If 
  Loop 
End Proc
Procedure _HOCH[X,Y]
  N=FELD(X,Y)-3
  FELD(X,Y)=1
  '
  Bob N,X*11+89,Y*11,N
  Paste Icon X*11+88,Y*11,1
  Channel 3 To Bob N
  '
  Repeat 
    Add I,11
    Dec Y
  Until FELD(X,Y)<>1
  Add I,-11
  '
  A=5*I/11
  Amal 2,"M 0,"+Str$(-I)+","+Str$(A)
  Amal 3,"M 0,"+Str$(-I)+","+Str$(A)
  Amal On 2
  Amal On 3
  While Chanmv(2) : Wend 
  While Chanmv(3) : Wend 
  '
  FELD(X,Y+1)=N+3
  Paste Bob X*11+89,(Y+1)*11,N
  Bob Off N
End Proc
Procedure _RUNTER[X,Y]
  N=FELD(X,Y)-3
  FELD(X,Y)=1
  '
  Bob N,X*11+89,Y*11,N
  Paste Icon X*11+88,Y*11,1
  Channel 3 To Bob N
  '
  Repeat 
    Add I,11
    Inc Y
  Until FELD(X,Y)<>1
  Add I,-11
  Dec Y
  '
  A=5*I/11
  Amal 2,"M 0,"+Str$(I)+","+Str$(A)
  Amal 3,"M 0,"+Str$(I)+","+Str$(A)
  Amal On 2
  Amal On 3
  While Chanmv(2) : Wend 
  While Chanmv(3) : Wend 
  '
  FELD(X,Y)=N+3
  Paste Bob X*11+89,Y*11,N
  Bob Off N
End Proc
Procedure _LINKS[X,Y]
  N=FELD(X,Y)-3
  FELD(X,Y)=1
  '
  Bob N,X*11+89,Y*11,N
  Paste Icon X*11+88,Y*11,1
  Channel 3 To Bob N
  '
  Repeat 
    Add I,11
    Dec X
  Until FELD(X,Y)<>1
  Add I,-11
  Inc X
  '
  A=5*I/11
  Amal 2,"M"+Str$(-I)+",0,"+Str$(A)
  Amal 3,"M"+Str$(-I)+",0,"+Str$(A)
  Amal On 2
  Amal On 3
  While Chanmv(2) : Wend 
  While Chanmv(3) : Wend 
  '
  FELD(X,Y)=N+3
  Paste Bob X*11+89,Y*11,N
  Bob Off N
End Proc
Procedure _RECHTS[X,Y]
  N=FELD(X,Y)-3
  FELD(X,Y)=1
  '
  Bob N,X*11+89,Y*11,N
  Paste Icon X*11+88,Y*11,1
  Channel 3 To Bob N
  '
  Repeat 
    Add I,11
    Inc X
  Until FELD(X,Y)<>1
  Add I,-11
  Dec X
  '
  A=5*I/11
  Amal 2,"M"+Str$(I)+",0,"+Str$(A)
  Amal 3,"M"+Str$(I)+",0,"+Str$(A)
  Amal On 2
  Amal On 3
  While Chanmv(2) : Wend 
  While Chanmv(3) : Wend 
  '
  FELD(X,Y)=N+3
  Paste Bob X*11+89,Y*11,N
  Bob Off N
End Proc
Procedure _CHECK
  For I=0 To 20-HOCH
    For I2=0 To 20-BREIT
      If FELD(I2,I)>3
        Add I2,-BACK
        For A=I To I+HOCH
          For B=I2 To I2+BREIT
            C=FELD(B,A)
            If C<4 : C=0 Else Add C,-3 : End If 
            N$=N$+Str$(C)-" "
          Next B
        Next A
        I=20 : I2=20
      End If 
    Next I2
  Next I
  If N$=CODE$ Then CHECKOK=True
End Proc
Procedure _GETBALLS
  Bob Off 
  Wait 10
  For I=0 To 20
    For I2=0 To 20
      N=FELD(I2,I)-3
      If N>0
        If MUSE=False : Sam Play 1,1,8000 : End If 
        For A=0 To 6
          Screen Copy 0,88+A*12,71,97+A*12,81 To Physic,I2*11+89,I*11
          Screen Copy 0,88+A*12,71,97+A*12,81 To Logic,I2*11+89,I*11
          Wait 3
        Next A
        Add PUNKTE,10+LEVEL
        _PUNKTE
      End If 
    Next I2
  Next I
  '
  If TM>0
    For I=1 To TM
      Dec TM
      If TM>9 : TM$="" Else TM$="0" : End If 
      _TEXT[6,109,TM$+Str$(TM)-" "]
      Add PUNKTE,100
      If MUSE=False : Sam Play 1,2,12000 : End If 
      _PUNKTE
      Wait 8
    Next I
  End If 
  If TS>9
    A=TS/10
    For I=1 To A
      Add TS,-10
      If TS>9 : TS$="" Else TS$="0" : End If 
      _TEXT[51,109,TS$+Str$(TS)-" "]
      Add PUNKTE,10
      If MUSE=False : Sam Play 1,2,16000 : End If 
      _PUNKTE
      Wait 5
    Next I
  End If 
  If TS>0
    For I=1 To TS
      Dec TS
      _TEXT[66,109,Str$(TS)-" "]
      Add PUNKTE,1
      If MUSE=False : Sam Play 1,2,16000 : End If 
      _PUNKTE
      Wait 5
    Next I
  End If 
  '
End Proc
Procedure _ALLDONE
  Screen Open 1,320,256,16,Lowres
  Screen Hide 
  Flash Off 
  Cls 0
  For I=0 To 16 : Colour I,$0 : Next I
  Screen Copy 0,0,191,203,219 To 1,59,10
  _TEXT[0,68,"you have cleared all"]
  _TEXT[0,85,"levels of colorix. as"]
  _TEXT[0,102,"bonus for your fine"]
  _TEXT[0,119,"work you get a nice"]
  _TEXT[0,136,"cheatmode:"]
  N$=Chr$($52)+Chr$($49)+Chr$($47)+Chr$($48)+Chr$($54)+Chr$($20)
  N$=N$+Chr$($53)+Chr$($48)+Chr$($49)+Chr$($46)+Chr$($54)+Chr$($20)
  N$=N$+Chr$($2B)+Chr$($20)
  N$=N$+Chr$($48)+Chr$($45)+Chr$($4C)+Chr$($50)
  _TEXT[0,168,N$]
  _TEXT[0,185,"SETS THE STARTLEVEL!"]
  _TEXT[0,202,"SKIPS A COLORIXLEVEL!"]
  _TEXT[7,240,"ßtry "+Chr$($64)+Chr$($61)+Chr$($6D)+Chr$($6E)+Chr$($65)+Chr$($64)+" of mineß"]
  Screen Show 
  Set Rainbow 0,1,30,"(1,1,15)(1,-1,15)","",""
  Rainbow 0,0,273,32
  Fade 2,,$FFF,$FFF,,$900,$C00,$F00,$70,$A1,$F0,$D91,$EC1,$FF0,$A,$C,$F
  While Fire(1)=0 : Wend 
  Fade 2 : Wait 40
End Proc
Procedure _EINTRAGEN
  Cls 0
  _TEXT[56,30,"CONGRATUALTION"]
  _TEXT[7,70,"you have entered the"]
  _TEXT[28,90,"colorix-highscore"]
  _TEXT[70,150,"............"]
  Set Rainbow 0,0,30,"(1,1,15)(1,-1,15)","",""
  Rainbow 0,0,182,32
  Fade 2,,$FFF : Wait 40
  Clear Key 
  Repeat 
    N=Asc(Inkey$)
    If N>13 and I<12 and N<>44
      N$=N$+Chr$(N)
      I=Len(N$)
      _TEXT[70,150,N$+String$(".",12-I)]
    End If 
    If N=8 and I>0
      Dec I
      N$=Left$(N$,I)
      _TEXT[70,150,N$+String$(".",12-I)]
    End If 
  Until N=13
  If N$="" Then N$="C.Applegateß"
  HNAME$(8)=N$ : HSCORE(8)=PUNKTE
  For I=0 To 7
    For I2=I+1 To 8
      If HSCORE(I2)>HSCORE(I)
        Swap HSCORE(I),HSCORE(I2)
        Swap HNAME$(I),HNAME$(I2)
      End If 
    Next I2
  Next I
  EINTRAGEN=True
  Fade 2
  Rainbow 0,0,0,0
  Wait 30
End Proc
Procedure _CONTINUE
  If CONTINUE=0 Then _GAMEOVER : Pop Proc
  Fade 2 : Wait 30
  Bob Off 
  Cls 0
  _TEXT[28,20,"will you continue"]
  _TEXT[35,40,"the last level ?"]
  _TEXT[126,90,"YES"]
  _TEXT[133,120,"NO"]
  _TEXT[54,150,"I DO NOT KNOW"]
  _TEXT[63,215,"CONTINUES #"+Str$(CONTINUE)-" "]
  Set Rainbow 0,0,30,"","","(1,1,15)(1,-1,15)"
  Rainbow 0,0,122,32
  Fade 2,,$FFF : Wait 30
  Y=1
  Repeat 
    While Joy(1)=0 : Wend 
    If Joy(1)=1 : Add Y,-1,1 To 3 : End If 
    If Joy(1)=2 : Add Y,1,1 To 3 : End If 
    If Y=1
      Set Rainbow 0,0,30,"","","(1,1,15)(1,-1,15)"
      Rainbow 0,0,122,32
    End If 
    If Y=2
      Set Rainbow 0,0,30,"","(1,1,15)(1,-1,15)",""
      Rainbow 0,0,152,32
    End If 
    If Y=3
      Set Rainbow 0,0,30,"(1,1,15)(1,-1,15)","",""
      Rainbow 0,0,182,32
    End If 
    Wait 10
  Until Joy(1)=16
  If Y=3 Then Y=Rnd(1)+1
  If Y=1 Then CHECKOK=True : Dec LEVEL : Dec CONTINUE : Add PUNKTE,-PUNKTE/5
  Fade 2
  Rainbow 0,0,0,0
  Wait 30
  If Y=2 Then _GAMEOVER
End Proc
Procedure _GAMEOVER
  Fade 2 : Wait 30
  Bob Off : Cls 0
  _TEXT[93,102,"GAME OVER"]
  Fade 2 To 0 : Wait 50
  While Fire(1)=False and Asc(Inkey$)=0 : Wend 
End Proc
Procedure _ZEIT
  Add TS,-1,0 To 60
  If TS=60
    TS=59
    Add TM,-1
  End If 
  If TM>9 Then TM$="" Else TM$="0"
  If TS>9 Then TS$="" Else TS$="0"
  TM$=TM$+Str$(TM)-" "
  TS$=TS$+Str$(TS)-" "
  _TEXT[6,109,TM$+":"+TS$]
  Every On 
End Proc
Procedure _PAUSE
  Fade 2 : Wait 40
  Screen Open 2,96,32,2,Lowres
  Cls 0
  Colour 1,$707
  Screen Display 2,246,132,,
  Set Rainbow 0,0,30,"(1,1,15)(1,-1,15)","","(1,1,15)(1,-1,15)"
  Rainbow 0,0,132,32
  _TEXT[14,10,"PAUSE"]
  Fade 2,,$FFF
  While Fire(1)=False and Asc(Inkey$)=False : Wend 
  Rainbow 0,0,0,0
  Fade 2 : Wait 30
  Screen Close 2
  Fade 2 To 0 : Wait 30
  Clear Key 
End Proc
Procedure _LOAD
  Inc LEVEL
  CODE$=""
  CHECKOK=False
  '
  L$="Levels/lev"+Str$(LEVEL)-" "
  If Exist(L$)
    Open In 1,L$
      For I=0 To 20
        Input #1,N$
        For I2=0 To 20
          A$=Mid$(N$,I2+1,1)
          FELD(I2,I)=Asc(A$)-65
        Next I2
      Next I
      For I=0 To 8
        Input #1,N$
        For I2=0 To 8
          A$=Mid$(N$,I2+1,1)
          KLEINFELD(I2,I)=Val(A$)
        Next I2
      Next I
      Input #1,TM
      Input #1,TS
      Input #1,BACK
      Input #1,HOCH
      Input #1,BREIT
    Close 1
  End If 
  '
  '-*- Code ermitteln -*-
  For I=0 To 8
    For I2=0 To 8
      If KLEINFELD(I2,I)<>0
        Add I2,-BACK
        For A=I To I+HOCH
          For B=I2 To I2+BREIT
            CODE$=CODE$+Str$(KLEINFELD(B,A))-" "
          Next B
        Next A
        I=8 : I2=8
      End If 
    Next I2
  Next I
End Proc
Procedure _SPIELFELD
  Screen Open 1,320,256,32,Lowres
  Screen Hide 
  Flash Off 
  For I=0 To 31 : Colour I,0 : Next I
  Cls 0
  Screen Show 
  '
  Ink 0
  For I=0 To 20
    For I2=0 To 20
      N=FELD(I,I2)
      If N
        Screen Copy 0,(N-1)*11,0,N*11,11 To 1,88+I*11,I2*11
      Else 
        Bar 88+I*11,I2*11 To 99+I*11,I2*11+11
      End If 
    Next I2
  Next I
  '
  Screen Copy 0,0,71,86,157 To 1,0,0
  For I=0 To 8
    For I2=0 To 8
      N=KLEINFELD(I,I2)
      If N
        Screen Copy 0,132+(N-1)*6,0,132+N*6,6 To 1,8+I*8,8+I2*8
      End If 
    Next I2
  Next I
  '
  If TM>9 Then TM$="" Else TM$="0"
  If TS>9 Then TS$="" Else TS$="0"
  TM$=TM$+Str$(TM)-" "
  TS$=TS$+Str$(TS)-" "
  _TEXT[14,93,"TIME"]
  _TEXT[6,109,TM$+":"+TS$]
  '
  N$=""
  If LEVEL<100 Then N$="0"
  If LEVEL<10 Then N$="00"
  _TEXT[6,148,"LEVEL"]
  _TEXT[20,164,N$+Str$(LEVEL)-" "]
  '
  _TEXT[0,203,"POINTS"]
  _PUNKTE
  '
  Double Buffer 
  '
  Bob 14,94,6,14
  '
  Fade 2 To 0 : Wait 30
End Proc
Procedure _PUNKTE
  If PUNKTE<100000 Then N$="0"
  If PUNKTE<10000 Then N$="00"
  If PUNKTE<1000 Then N$="000"
  If PUNKTE<100 Then N$="0000"
  If PUNKTE<10 Then N$="00000"
  _TEXT[0,219,N$+Str$(PUNKTE)-" "]
End Proc
Procedure _INSTALLGFX
  Unpack 16 To 0
  Screen Hide 
  For I=1 To 9
    Get Bob I,23+I*11,0 To 33+I*11,11
  Next I
  For I=0 To 3
    Get Bob I+10,186+I*12,0 To 197+I*12,12
  Next I
  Get Bob 14,233,0 To 249,16
  Get Icon 1,0,0 To 10,10
  Make Icon Mask 
  '
  Erase 16
  '
  If Exist("colorixhigh")
    Open In 1,"colorixhigh"
      For I=0 To 8
        Input #1,HNAME$(I)
        Input #1,HSCORE(I)
      Next I
    Close 1
  Else 
    For I=0 To 8
      HNAME$(I)="............"
    Next I
  End If 
  '
  If Exist("Levels/levanz")
    Open In 1,"Levels/levanz"
      Input #1,LEVELMAX
    Close 1
  Else 
    LEVELMAX=32
  End If 
  Wait 150
  If Fast Free+Chip Free>300000
    FFCF=True
    MUSE=True
    Music 1
  Else 
    Erase 3
  End If 
  Led Off 
End Proc
Procedure _TEXT[X,Y,N$]
  A=Len(N$)
  T1$='ABCDEFGHIJKLMNOPQRSTUV'
  T2$='WXYZabcdefghijklmnopqr'
  T3$='stuvwxyz0123456789.:*#'
  T4$='-+/!"$%`()=?~<>^_;©®ß '
  For I=1 To A
    A$=Mid$(N$,I,1)
    If Instr(T1$,A$) : C=Instr(T1$,A$) : B=18 : End If 
    If Instr(T2$,A$) : C=Instr(T2$,A$) : B=31 : End If 
    If Instr(T3$,A$) : C=Instr(T3$,A$) : B=44 : End If 
    If Instr(T4$,A$) : C=Instr(T4$,A$) : B=57 : End If 
    Screen Copy 0,(C-1)*14,B,C*14-2,B+13 To Physic,X+(I-1)*15,Y
    Screen Copy 0,(C-1)*14,B,C*14-2,B+13 To Logic,X+(I-1)*15,Y
  Next I
End Proc
Procedure _INTRO
  Screen Open 1,320,256,8,Lowres
  Screen Hide 
  Hide 
  Flash Off 
  For I=0 To 7 : Colour I,$0 : Next I
  Cls 0
  Screen Show 
  Screen Copy 0,0,158,286,190 To 1,14,98
  Fade 1,,$FFF,$FFF,$FFF,$FFF,$FFF,$FFF,$FFF : Wait 17
  Fade 2,,$600,$800,$A20,$A40,$C60,$C80,$EC0 : Wait 200
  Fade 1,,$FFF,$FFF,$FFF,$FFF,$FFF,$FFF,$FFF : Wait 17
  Fade 2 : Wait 51 : Cls 0
  _TEXT[102,100,"presents"]
  Fade 2 To 0 : Wait 150
  Fade 2 : Wait 40 : Cls 0
  _TEXT[144,65,"an"]
  _TEXT[98,102,"amosgame"]
  _TEXT[144,138,"by"]
  Fade 2 To 0 : Wait 150
  Fade 2 : Wait 40 : Cls 0
  _TEXT[39,102,"VOLKER STEPPRATH"]
  Fade 2 To 0 : Wait 157
  Fade 2 : Wait 30 : Cls 0
End Proc